Mogre Basic Tutorial VB 6
From Ogre Wiki
Basic Tutorial 6: Overlay's and Publishing
Original version by Aeauseth
Any problems you encounter while working with this tutorial should be posted to the Mogre Forums.
Contents |
Prerequisites
This tutorial assumes you have knowledge of VB.NET programming and are able to setup and compile an Mogre application (if you have trouble setting up your application, see Mogre Basic Tutorial VB 0 for a detailed setup walkthrough).
Introduction
In this tutorial you will learn how to use the DebugOverlay to display FPS information. You will also learn how to use an overlay to show a mouse cursor. Finally I will show that you can publish this project using the Click Once technique.
As you go through the tutorial you should be slowly adding code to your own project and watching the results as we build it.
Getting Started
As with the previous tutorials, we will be using a pre-constructed code:
Imports Mogre
Module Module1
Public myKeyboard As MOIS.Keyboard
Public myMouse As MOIS.Mouse
Public myCamera As Camera
Public MyWindow As RenderWindow
Public myTranslation As Vector3 = Vector3.ZERO
Public Quitting As Boolean = False
Public myRotating As Boolean = False
Sub Main()
Try
'Creating the Root Object
Dim myRoot As Root = New Root("Plugins.cfg", "ogre.cfg", "ogre.log")
'Defining the Resources
Dim cf As New ConfigFile
cf.Load("resources.cfg", vbTab + ":=", True)
Dim seci As ConfigFile.SectionIterator = cf.GetSectionIterator
Dim secName As String, typeName As String, archName As String
While (seci.MoveNext())
secName = seci.CurrentKey
Dim settings As ConfigFile.SettingsMultiMap = seci.Current
For Each pair As KeyValuePair(Of String, String) In settings
typeName = pair.Key
archName = pair.Value
ResourceGroupManager.Singleton.AddResourceLocation(archName, typeName, secName)
Next
End While
'Setting up the RenderSystem
If Not myRoot.RestoreConfig Then
If Not myRoot.ShowConfigDialog Then
Exit Sub
End If
End If
'Creating the Render Window
MyWindow = myRoot.Initialise(True, "Ogre RenderWindow")
AddHandler myRoot.FrameStarted, AddressOf FrameStarted
'Initializing Resource Groups
TextureManager.Singleton.DefaultNumMipmaps = 5
ResourceGroupManager.Singleton.InitialiseAllResourceGroups()
'Creating the Scene
Dim myScene As SceneManager = myRoot.CreateSceneManager(SceneType.ST_GENERIC)
myCamera = myScene.CreateCamera("Camera")
myRoot.AutoCreatedWindow.AddViewport(myCamera)
Dim myNinja As Entity = myScene.CreateEntity("ninja", "ninja.mesh")
myScene.RootSceneNode.CreateChildSceneNode.AttachObject(myNinja)
myCamera.Position = New Vector3(0, 200, -400)
myCamera.LookAt(myNinja.BoundingBox.Center)
'Overlay
'Input handler
InputClass.Init()
'The Render Loop
myRoot.StartRendering()
Catch ex As System.Runtime.InteropServices.SEHException
If OgreException.IsThrown Then
MsgBox(OgreException.LastException.FullDescription, MsgBoxStyle.Critical, _
"An Ogre exception has occured!")
Else
MsgBox(ex.ToString, "An error has occured")
End If
End Try
End Sub
Public Function FrameStarted(ByVal e As FrameEvent) As Boolean
'Capture buffered input
myKeyboard.Capture()
myMouse.Capture()
'Handle player/camera movement
InputClass.ProcessKeyboard()
myCamera.Position += myCamera.Orientation * myTranslation * e.timeSinceLastFrame
'Debug Overlay
Return Not Quitting
End Function
Public Class InputClass
Const TRANSLATE As Single = 200
Const ROTATE As Single = 0.003
Shared Sub Init()
'Keyboard
Dim windowHnd As Integer
MyWindow.GetCustomAttribute("WINDOW", windowHnd)
Dim myInputManager As MOIS.InputManager = MOIS.InputManager.CreateInputSystem(windowHnd)
myKeyboard = myInputManager.CreateInputObject(MOIS.Type.OISKeyboard, True)
AddHandler myKeyboard.KeyPressed, AddressOf InputClass.KeyPressed
AddHandler myKeyboard.KeyReleased, AddressOf InputClass.KeyReleased
'Mouse
myMouse = myInputManager.CreateInputObject(MOIS.Type.OISMouse, True)
AddHandler myMouse.MouseMoved, AddressOf InputClass.MouseMovedListener
AddHandler myMouse.MousePressed, AddressOf InputClass.MousePressedListener
AddHandler myMouse.MouseReleased, AddressOf InputClass.MouseReleasedListener
End Sub
Shared Function KeyPressed(ByVal e As MOIS.KeyEvent) As Boolean
Select Case e.key
Case MOIS.KeyCode.KC_ESCAPE
Quitting = True
End Select
Return Nothing
End Function
Shared Function KeyReleased(ByVal e As MOIS.KeyEvent) As Boolean
'This function is just a placeholder
'It is unlikely you will ever use this
'Typically you either process unbuffered keyboard input (as in ProcessKeyboard)
'or you process buffered Keypress
Return Nothing
End Function
Shared Sub ProcessKeyboard()
'This Sub is typically called via the FrameStarted event.
'Clear previous translation
myTranslation.z = 0
myTranslation.x = 0
myTranslation.y = 0
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_UP) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_W) Then
myTranslation.z += -TRANSLATE
End If
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_S) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_DOWN) Then
myTranslation.z += TRANSLATE
End If
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_A) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_LEFT) Then
myTranslation.x += -TRANSLATE
End If
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_D) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_RIGHT) Then
myTranslation.x += TRANSLATE
End If
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_Q) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_PGUP) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_SPACE) Then
myTranslation.y += TRANSLATE
End If
If myKeyboard.IsKeyDown(MOIS.KeyCode.KC_Z) Or _
myKeyboard.IsKeyDown(MOIS.KeyCode.KC_PGDOWN) Then
myTranslation.y += -TRANSLATE
End If
End Sub
Shared Function MouseMovedListener(ByVal e As MOIS.MouseEvent) As Boolean
Static myLastX As Integer = e.state.X.abs
Static myLastY As Integer = e.state.Y.abs
If myRotating Then
myCamera.Yaw(e.state.X.rel * -ROTATE)
myCamera.Pitch(e.state.Y.rel * -ROTATE)
End If
End Function
Shared Function MousePressedListener(ByVal e As MOIS.MouseEvent, ByVal id As MOIS.MouseButtonID) As Boolean
If e.state.ButtonDown(MOIS.MouseButtonID.MB_Right) Then
myRotating = True
End If
End Function
Shared Function MouseReleasedListener(ByVal e As MOIS.MouseEvent, ByVal id As MOIS.MouseButtonID) As Boolean
If Not e.state.ButtonDown(MOIS.MouseButtonID.MB_Right) Then
myRotating = False
End If
End Function
End Class
End Module
Make sure you can compile and run the application before continuing. If you are having difficulty, refer to the project setup guide or post to the forums. You should see a Ninja.
Overlays
For simplicity we will use an overlay include with the OgreSDK. Add the following code:
'Overlay
Dim myPanelOverlay As Overlay = OverlayManager.Singleton.GetByName("Core/DebugOverlay")
myPanelOverlay.Show()
The Overlay manager will search thru all the resources until it finds "Core/DebugOverlay", which in this case is in C:\OgreSDK\media\packs\OgreCore.zip. Feel free to open the ZIP file to see it's contents. I won't discuss how to create your own overlay yet, you will have to wait until the intermediate tutorials are finished. For now go ahead and compile & run the code.
You should see the Ogre logo and a green box with FPS information. Wouldn't it be nice to actually see the FPS and triangle counts? Well add the following code to the FrameStarted handler:
'Debug Overlay
Dim myAvg As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/AverageFps")
Dim myCurr As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/CurrFps")
Dim myBest As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/BestFps")
Dim myWorst As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/WorstFps")
Dim myNumTris As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/NumTris")
Dim myNumBatches As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/NumBatches")
Dim myDebug As OverlayElement = OverlayManager.Singleton.GetOverlayElement("Core/DebugText")
myAvg.Caption = "Average FPS: " & Mogre.StringConverter.ToString(MyWindow.AverageFPS)
myCurr.Caption = "Current FPS: " & Mogre.StringConverter.ToString(MyWindow.LastFPS)
myBest.Caption = "Best FPS: " & Mogre.StringConverter.ToString(MyWindow.BestFPS)
myWorst.Caption = "Worst FPS: " & Mogre.StringConverter.ToString(MyWindow.WorstFPS)
myNumTris.Caption = "Triangle Count: " & Mogre.StringConverter.ToString(MyWindow.TriangleCount)
myNumBatches.Caption = "Batch Count: " & Mogre.StringConverter.ToString(MyWindow.BatchCount)
Now compile and run again. Move the camera around and watch the FPS change. You will probably have a FPS of 100+, on my system it is 800+. At most you only need 60 FPS. The FPS will drop as you add more entities to the scene.
Overlay Scripts
The overlay size and properties are stored in the OgreDebugPanel.overlay file. Here is the psudo code:
// Ogre overlay scripts
Core/DebugOverlay
{
zorder 500
// Stats block
container BorderPanel(Core/StatPanel)
{
metrics_mode pixels
vert_align bottom
left 5
top -107
width 220
height 102
material Core/StatsBlockCenter
border_size 1 1 1 1
border_material Core/StatsBlockBorder
border_topleft_uv 0.0000 1.0000 0.0039 0.9961
border_top_uv 0.0039 1.0000 0.9961 0.9961
border_topright_uv 0.9961 1.0000 1.0000 0.9961
border_left_uv 0.0000 0.9961 0.0039 0.0039
border_right_uv 0.9961 0.9961 1.0000 0.0039
border_bottomleft_uv 0.0000 0.0039 0.0039 0.0000
border_bottom_uv 0.0039 0.0039 0.9961 0.0000
border_bottomright_uv 0.9961 0.0039 1.0000 0.0000
container Panel(Core/BreakPanel)
{
metrics_mode pixels
left 5
top 22
width 210
height 1
material Core/StatsBreak
}
element TextArea(Core/CurrFps)
{
metrics_mode pixels
left 5
top 5
width 90
height 30
font_name BlueHighway
char_height 19
caption Current FPS:
colour_top 1 1 0.7
colour_bottom 1 1 0.7
}
element TextArea(Core/AverageFps)
{
metrics_mode pixels
left 5
top 25
width 90
height 30
font_name BlueHighway
char_height 16
caption AVERAGE FPS:
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
element TextArea(Core/WorstFps)
{
metrics_mode pixels
left 5
top 40
width 90
height 30
font_name BlueHighway
char_height 16
caption WORST FPS:
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
element TextArea(Core/BestFps)
{
metrics_mode pixels
left 5
top 55
width 90
height 30
font_name BlueHighway
char_height 16
caption BEST FPS:
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
element TextArea(Core/NumTris)
{
metrics_mode pixels
left 5
top 70
width 90
height 30
font_name BlueHighway
char_height 16
caption Triangle Count:
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
element TextArea(Core/NumBatches)
{
metrics_mode pixels
left 5
top 85
width 90
height 30
font_name BlueHighway
char_height 16
caption Batch Count:
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
element TextArea(Core/DebugText)
{
metrics_mode pixels
left 230
top 70
width 200
height 30
font_name BlueHighway
char_height 16
colour_top 0.5 0.7 0.5
colour_bottom 0.3 0.5 0.3
}
}
container Panel(Core/LogoPanel)
{
metrics_mode pixels
horz_align right
vert_align bottom
top -75
left -165
width 150
height 75
material Core/OgreText
}
}
// A silly example of how you would do a 3D cockpit
//Examples/KnotCockpit
//{
// zorder 100
// entity knot.mesh(hudKnot)
// {
// position 0 0 -50
// rotation 0 0 0 0
// }
//
//}
You can get a general idea how the panel is setup and how each overlay element is defined. Again you will have to wait for the intermediate tutorials if you want to create your own.
Publishing
Before we can publish our project we need to make sure all the files we need are listed in our Solution Explorer.
As you recall we took a few shortcuts and used several items from C:\OgreSDK. So we will need to prepare our project so it can stand on it's own.
Preperation
So lets add these items to our project now. Open the resources.cfg file and modify the paths as follows:
# Resource locations to be added to the 'boostrap' path # This also contains the minimum you need to use the Ogre example framework [Bootstrap] Zip=.\Media\packs/OgreCore.zip # Resource locations to be added to the default path [General] FileSystem=.\Media\ FileSystem=.\Media/fonts FileSystem=.\Media/materials/programs FileSystem=.\Media/materials/scripts FileSystem=.\Media/materials/textures FileSystem=.\Media/models FileSystem=.\Media/overlays FileSystem=.\Media/particle FileSystem=.\Media/gui FileSystem=.\Media/DeferredShadingMedia Zip=.\Media/packs/cubemap.zip Zip=.\Media/packs/cubemapsJS.zip Zip=.\Media/packs/dragon.zip Zip=.\Media/packs/fresneldemo.zip Zip=.\Media/packs/ogretestmap.zip Zip=.\Media/packs/skybox.zip
Now drag and drop the C:\OgreSDK\Media folder to your Solution Explorer. Ideally you would now set the properties of each of these files to "Copy if newer", but there is alot of them (ugly). I decided to modify my Tutuorial6.vbproj file and replace None Include="media with Content Include="media, which was much faster.
You may have noticed that we modified our "Defining the Resources" section of code to look in two places.
We also need to modify the paths of our Plugins.cfg file as follows:
# Defines plugins to load # Define plugin folder PluginFolder=./plugins # Define plugins Plugin=RenderSystem_Direct3D9 Plugin=RenderSystem_GL Plugin=Plugin_ParticleFX Plugin=Plugin_BSPSceneManager Plugin=Plugin_OctreeSceneManager Plugin=Plugin_CgProgramManager
Now right click on "Solution Explorer" and create a new folder called "plugins". Now right click on this "plugins" folder and add the existing items listed in the Plugins.cfg file. You should find these files in C:\OgreSDK\bin\release.
Verify that all the files in the plugins have theri Build Action set to 'Content', and the "Copy to Output" set to "Copy if newer"
Verify that all the remaining 'dll' and 'cfg' files in the main Solution Explorer have their Build Action set to 'Content'.
Compile and run to make sure everything still works!
Publish
On the menu bar select Project then click on the Publish tab. Pick a new folder on your hard drive, USB drive, or wherever. I recommend clicking the updates button and checking the auto updates before application starts.
Click the Publish Wizard, follow the prompts and your done. You can burn the publish directory to a CD if you like.
There are a couple of prequesites to running Ogre applications. You must have vcredist_x86.exe and DirectX Redistributables from November 2007 installed. It would be nice to include these as prerequisites to the publishing package, but I don't know how to do this. For now just download and include them with the rest of the package.
You can now take these files to a generic computer and run setup.exe. This is a very simple way to distribute your application.
Conclusion
You have seen how overlays can be used to provide 2D information in a static location. You have also seen that VB.NET can package up all the necessary files, refereneces and dll dependancies, so that you can publish your application. You may find that a custom or commercial setup applcation may be more suitable for your project.
You may have noticed that there are only 6 VB.NET basic tutorials, yet there are 8 ogre basic tutorials. In my opinion the use of CEGUI and other addins are not 'basic'. Look for addin tutorials in the VB.NET intermediate tutorials.
